// globals
int graviolicount = 10;
Graviton[] gravioli = new Graviton[graviolicount];

void setup(){
  size(200,200,P3D);
  for(int i=0; i<graviolicount; i++){
    gravioli[i] = new Graviton(); 
  }
}

void draw(){
  background(0);
  for(int i=0; i<graviolicount; i++){
    pushMatrix();
    gravioli[i].draw();
    popMatrix();
  }
}

class Graviton{
  int x, y, radius, offset;
  int num = 255;
  float cnt, detail, rotx, roty, rotz, rotxspeed, rotyspeed, rotzspeed;
  int[] xlist = new int[num];
  int[] ylist = new int[num];
  
  Graviton(){
    radius = int(width * 0.4);   // orbit size
    offset = int(width / 2);     // center
    detail = 6.28 / 1000;        // speed
    cnt = random(-3.14, 3.14);   // starting location
    rotx = 0;
    roty = 0;
    rotz = 0;
    rotxspeed = random(-0.1, 0.1);
    rotyspeed = random(-0.1, 0.1);
    rotzspeed = random(-0.1, 0.1);
    x = int(sin(cnt) * radius + offset);
    y = int(cos(cnt) * radius + offset);
    for(int i=0; i<num; i++){    // fill array elements with starting location
      xlist[i] = x;
      ylist[i] = y;  
    }
  }
 
  void draw(){
    translate(width/2, -width/2, 0);
    //rotateX(radians(rotx));
    rotateY(radians(roty));
    //rotateZ(radians(rotz));
    pushMatrix();
    translate(-width/2, width/2, 0);
    this.move();
    this.trail();
    popMatrix();
    roty += rotyspeed;
    rotx += rotxspeed;
    rotz += rotzspeed;
  }
 
  void move(){
    x = int(sin(cnt) * radius + offset);
    y = int(cos(cnt) * radius + offset);
    cnt = cnt + detail;
    if (cnt > 3.14){
      cnt = -3.14;
    }
  }
 
  void trail(){
    for(int i=1; i<num; i++){  // shift all elements 1 place to the left
      xlist[i-1] = xlist[i];
      ylist[i-1] = ylist[i];
    }
    xlist[num-1] = x;          // add new locaton to end of each array
    ylist[num-1] = y;
    for(int i=1; i<num; i++){  // draw lines between each history point
      //stroke(i);
      stroke(255, 255, 255, i*0.5);  // alpha blending is slow
      line(xlist[i-1], ylist[i-1], 0, xlist[i], ylist[i], 0);
    }
  } 
}