// globals
float mainrotation = 0;
boolean remove = false;
Graviton[] gravioli = new Graviton[0];


void setup(){
  size(200,200,P3D);
  background(0);
}

void draw(){
  fill(0,0,0,1);
  rect(0,0,width,height);
  translate(width/2, height/2);
  rotateY(radians(mainrotation));
  translate(-width/2, -height/2);
  for(int i=0; i<gravioli.length; i++){
    gravioli[i].draw();
  }
  mainrotation += 0.1;
}

void keyPressed(){
  remove = true;
}

void keyReleased(){
  remove = false;
}

void mousePressed(){
  if(remove && gravioli.length > 0){
    gravioli = removeGravioli(gravioli);
  } else {
    gravioli = addGravioli(gravioli);
  }
}

class Graviton{
  int x, x1, x2, y, y1, y2, radius, offset, r, g, b;
  int num = 100;
  float cnt, detail, rotx, roty, rotz;
  int[] xlist = new int[num];
  int[] ylist = new int[num];
  Stack xstack = new Stack();
  Stack ystack = new Stack();
  
  Graviton(){
    radius = int(width * 0.4);         // orbit size
    offset = int(width / 2);           // center
    detail = 6.28 / random(200,500);  // speed
    cnt = random(-3.14, 3.14);         // starting location
    rotx = random(-3.14, 3.14);
    roty = random(-3.14, 3.14);
    rotz = random(-3.14, 3.14);
    r = 0;
    g = int(random(150, 255));
    b = int(random(150, 255));
    x = int(sin(cnt) * radius + offset);
    y = int(cos(cnt) * radius + offset);
    for(int i=0; i<num; i++){          // fill array elements with starting location
      xlist[i] = x;
      ylist[i] = y;
    }
  }
 
  void draw(){
    translate(width/2, height/2, 0);
    rotateY(roty);
    rotateX(rotx);
    translate(-width/2, -height/2, 0);
    this.move();
    this.trail();
  }
 
  void move(){
    x = int(sin(cnt) * radius + offset);
    y = int(cos(cnt) * radius + offset);
    cnt = cnt + detail;
    if (cnt > 3.14){
      cnt = -3.14;
    }
  }
 
  void trail(){
    for(int i=1; i<num; i++){  // shift all elements 1 place to the left
      xlist[i-1] = xlist[i];
      ylist[i-1] = ylist[i];
    }
    xlist[num-1] = x;          // add new locaton to end of each array
    ylist[num-1] = y;
    for(int i=1; i<num; i++){  // draw lines between each history point
      stroke(r, g, b, i);      // alpha blending is slow
      line(xlist[i-1], ylist[i-1], 0, xlist[i], ylist[i], 0);
    }
  } 
}

Graviton[] addGravioli(Graviton[] g){
  Graviton[] newg = new Graviton[g.length+1];
  System.arraycopy(g,0,newg,0,g.length);
  newg[g.length] = new Graviton();
  return newg;
}

Graviton[] removeGravioli(Graviton[] g){
  Graviton[] newg = new Graviton[g.length-1];
  System.arraycopy(g,0,newg,0,g.length-1);
  return newg;
}